Checkpoint port of xv6 to x86-64. Passed usertests on 2 processors a few times.

The x86-64 doesn't just add two levels to page tables to support 64 bit
addresses, but is a different processor. For example, calling conventions,
system calls, and segmentation are different from 32-bit x86. Segmentation is
basically gone, but gs/fs in combination with MSRs can be used to hold a
per-core pointer. In general, x86-64 is more straightforward than 32-bit
x86. The port uses code from sv6 and the xv6 "rsc-amd64" branch.

A summary of the changes is as follows:

- Booting: switch to grub instead of xv6's bootloader (pass -kernel to qemu),
because xv6's boot loader doesn't understand 64bit ELF files.  And, we don't
care anymore about booting.

- Makefile: use -m64 instead of -m32 flag for gcc, delete boot loader, xv6.img,
bochs, and memfs. For now dont' use -O2, since usertests with -O2 is bigger than
MAXFILE!

- Update gdb.tmpl to be for i386 or x86-64

- Console/printf: use stdarg.h and treat 64-bit addresses different from ints
  (32-bit)

- Update elfhdr to be 64 bit

- entry.S/entryother.S: add code to switch to 64-bit mode: build a simple page
table in 32-bit mode before switching to 64-bit mode, share code for entering
boot processor and APs, and tweak boot gdt.  The boot gdt is the gdt that the
kernel proper also uses. (In 64-bit mode, the gdt/segmentation and task state
mostly disappear.)

- exec.c: fix passing argv (64-bit now instead of 32-bit).

- initcode.c: use syscall instead of int.

- kernel.ld: load kernel very high, in top terabyte.  64 bits is a lot of
address space!

- proc.c: initial return is through new syscall path instead of trapret.

- proc.h: update struct cpu to have some scratch space since syscall saves less
state than int, update struct context to reflect x86-64 calling conventions.

- swtch: simplify for x86-64 calling conventions.

- syscall: add fetcharg to handle x86-64 calling convetions (6 arguments are
passed through registers), and fetchaddr to read a 64-bit value from user space.

- sysfile: update to handle pointers from user space (e.g., sys_exec), which are
64 bits.

- trap.c: no special trap vector for sys calls, because x86-64 has a different
plan for system calls.

- trapasm: one plan for syscalls and one plan for traps (interrupt and
exceptions). On x86-64, the kernel is responsible for switching user/kernel
stacks. To do, xv6 keeps some scratch space in the cpu structure, and uses MSR
GS_KERN_BASE to point to the core's cpu structure (using swapgs).

- types.h: add uint64, and change pde_t to uint64

- usertests: exit() when fork fails, which helped in tracking down one of the
bugs in the switch from 32-bit to 64-bit

- vectors: update to make them 64 bits

- vm.c: use bootgdt in kernel too, program MSRs for syscalls and core-local
state (for swapgs), walk 4 levels in walkpgdir, add DEVSPACETOP, use task
segment to set kernel stack for interrupts (but simpler than in 32-bit mode),
add an extra argument to freevm (size of user part of address space) to avoid
checking all entries till KERNBASE (there are MANY TB before the top 1TB).

- x86: update trapframe to have 64-bit entries, which is what the processor
pushes on syscalls and traps.  simplify lgdt and lidt, using struct desctr,
which needs the gcc directives packed and aligned.

TODO:
- use int32 instead of int?
- simplify curproc(). xv6 has per-cpu state again, but this time it must have it.
- avoid repetition in walkpgdir
- fix validateint() in usertests.c
- fix bugs (e.g., observed one a case of entering kernel with invalid gs or proc

1 files changed, 127 insertions, 23 deletions

diff --git a/trapasm.S b/trapasm.S
index da8aefc..b6dbb1a 100644
--- a/trapasm.S
+++ b/trapasm.S
@@ -1,32 +1,136 @@
+#include "param.h"
+#include "x86.h"	
 #include "mmu.h"
-
-  # vectors.S sends all traps here.
+	
+# vectors.S sends all traps here.
 .globl alltraps
 alltraps:
   # Build trap frame.
-  pushl %ds
-  pushl %es
-  pushl %fs
-  pushl %gs
-  pushal
-  
-  # Set up data segments.
-  movw $(SEG_KDATA<<3), %ax
-  movw %ax, %ds
-  movw %ax, %es
+  push %r15
+  push %r14
+  push %r13
+  push %r12
+  push %r11
+  push %r10
+  push %r9
+  push %r8
+  push %rdi
+  push %rsi
+  push %rbp
+  push %rdx
+  push %rcx
+  push %rbx
+  push %rax
 
-  # Call trap(tf), where tf=%esp
-  pushl %esp
+  cmpw $KCSEG, 32(%rsp)   # compare to saved cs
+  jz 1f 
+  swapgs
+  
+1:mov  %rsp, %rdi  # frame in arg1
   call trap
-  addl $4, %esp
 
-  # Return falls through to trapret...
+# Return falls through to trapret...
 .globl trapret
 trapret:
-  popal
-  popl %gs
-  popl %fs
-  popl %es
-  popl %ds
-  addl $0x8, %esp  # trapno and errcode
-  iret
+  cli
+  cmpw $KCSEG, 32(%rsp)  # compare to saved cs
+  jz 1f
+  swapgs
+
+1:pop %rax
+  pop %rbx
+  pop %rcx
+  pop %rdx
+  pop %rbp
+  pop %rsi
+  pop %rdi
+  pop %r8
+  pop %r9
+  pop %r10
+  pop %r11
+  pop %r12
+  pop %r13
+  pop %r14
+  pop %r15
+
+  add $16, %rsp  # discard trapnum and errorcode
+  iretq
+#PAGEBREAK!
+
+# syscall_entry jumps here after syscall instruction
+.globl sysentry
+sysentry:  # Build trap frame.
+  // load kernel stack address
+  swapgs
+  movq  %rax, %gs:0  // save %rax in syscallno of cpu entry
+  movq  %rsp, %gs:8  // user sp
+  movq  %gs:16, %rax  // proc entry
+  
+  movq  %ss:0(%rax), %rax // load kstack from proc
+  addq  $(KSTACKSIZE), %rax
+
+  movq  %rax, %rsp
+  movq  %gs:0, %rax  // restore rax
+
+  // push usp
+  push $0
+  push %gs:8
+  // safe eflags and eip
+  push %r11
+  push $UCSEG
+  push %rcx
+  // push errno and trapno to make stack look like a trap
+  push $0
+  push $64
+
+  // push values on kernel stack
+  push %r15
+  push %r14
+  push %r13
+  push %r12
+  push %r11
+  push %r10
+  push %r9
+  push %r8
+  push %rdi
+  push %rsi
+  push %rbp
+  push %rdx
+  push %rcx
+  push %rbx
+  push %rax
+
+  mov  %rsp, %rdi  # frame in arg1
+
+  call trap
+#PAGEBREAK!
+
+# Return falls through to trapret...
+.globl sysexit
+sysexit:
+  # to make sure we don't get any interrupts on the user stack while in
+  # supervisor mode.  insufficient?  (see vunerability reports for sysret)
+  cli
+  
+  pop %rax
+  pop %rbx
+  pop %rcx
+  pop %rdx
+  pop %rbp
+  pop %rsi
+  pop %rdi
+  pop %r8
+  pop %r9
+  pop %r10
+  pop %r11
+  pop %r12
+  pop %r13
+  pop %r14
+  pop %r15
+
+  add $(5*8), %rsp  # discard trapnum, errorcode, rip, cs and rflags
+  mov (%rsp),%rsp  # switch to the user stack
+  swapgs	
+
+  sysretq
+